10 REM >ColClsh
   20 REM by Steven Flintham
   30 REM
   40 REM Demonstrate different colour combinations
   50 REM
   60 REM Sunday 6th September 1992
   70 :
   80 MODE 7
   90 VDU 23;8202;0;0;0;
  100 PROCdisable
  110 PROCinit
  120 PROCshow_clashes
  130 MODE 7
  140 PROCenable
  150 END
  160 :
  170 DEF PROCdisable
  180 *FX229,1
  190 *FX4,2
  200 ENDPROC
  210 :
  220 DEF PROCinit
  230 ON ERROR MODE 7:REPORT:PRINT " at line ";ERL:PROCenable:END
  240 DIM colour$(7)
  250 RESTORE
  260 FOR read%=0 TO 7
  270 READ colour$(read%)
  280 NEXT
  290 ENDPROC
  300 :
  310 DATA black,red,green,yellow,blue,magenta,cyan,white
  320 :
  330 DEF PROCenable
  340 *FX229,0
  350 *FX4,0
  360 ENDPROC
  370 :
  380 DEF PROCtitle(title$,fore%,back%)
  390 LOCAL x%
  400 x%=20-LEN(title$)/2
  410 PRINTTAB(x%-4,0);CHR$141;CHR$(128+back%);CHR$157;CHR$(128+fore%);title$;"  ";CHR$156
  420 PRINTTAB(x%-4,1);CHR$141;CHR$(128+back%);CHR$157;CHR$(128+fore%);title$;"  ";CHR$156
  430 ENDPROC
  440 :
  450 DEF PROCshow_clashes
  460 PROCtitle("Colour clash demonstration",3,4)
  470 VDU 28,0,24,39,3
  480 lines%=0
  490 FOR back%=0 TO 7
  500 FOR fore%=1 TO 7
  510 IF back%<>fore% THEN lines%=lines%+1:PRINT CHR$(128+back%);CHR$(156+ABS(back%<>0));CHR$(128+fore%);"This is ";colour$(fore%);" on ";colour$(back%);"."
  520 IF lines%=20 THEN PROCspace:CLS:lines%=0
  530 NEXT
  540 NEXT
  550 IF lines%<>0 THEN PROCspace
  560 ENDPROC
  570 :
  580 DEF PROCspace
  590 PRINT'"Press SPACE to continue...";
  600 *FX21
  610 REPEAT UNTIL GET=32
  620 ENDPROC