10 MODE 2:COLOUR 15
   20 PRINT TAB(6)"ANIMATION":VDU 5
   30 PROCball(150,900,100,-PI/6)
   40 PROCball(1190,945,75,-5*PI/4)
   50 PROCball(620,512,200,7*PI/6)
   60 PROCball(200,-292,400,0)
   70 PROCdots:PROCp
   80 VDU 19,1,6;0;19,2,4;0;19,15,10;0;29,0;0;
   90 FOR I%=9 TO 14:VDU 19,I%,0;0;:NEXT
  100 REPEAT
  110 FOR I%=3 TO 8
  120 J%=I%-1:IF J%=2 J%=8
  130 VDU 19,J%,4;0;19,I%,6;0;
  140 VDU 19,J%+6,0;0;19,I%+6,3;0;
  150 K9=INKEY(5)
  160 NEXT
  170 UNTIL FALSE
  180 DEF PROCball(X%,Y%,R%,Tilt)
  190  VDU 18;2,29,X%;Y%;:MOVE 0,R%
  200 FOR Phi=0 TO 6.4 STEP .15
  210  MOVE 0,0:PLOT 85,R%*SIN Phi,R%*COS Phi
  220 NEXT
  230 Col%=3
  240 FOR Phi=0 TO 3.1 STEP .1
  250 GCOL 0,Col%
  260 PROCarc(R%*COS Phi,R%,0,PI/2+Tilt,PI/2)
  270 Col%=Col%+1:IF Col%=9 Col%=3
  280 NEXT
  290 GCOL 0,1
  300 FOR Theta=.5 TO 2.5 STEP .5
  310 PROCarc(-R%/4*SIN Theta,R%*SIN Theta,R%*COS Theta,Tilt,1.5)
  320 NEXT
  330 ENDPROC
  340 DEF PROCarc(H%,W%,D%,Alpha,Beta)
  350 S=SIN Alpha:C=COS Alpha
  360 X%=W%*SIN Beta:Y%=D%+H%*COS Beta
  370 MOVE C*X%+S*Y%,C*Y%-S*X%
  380 FOR Gamma=-Beta TO Beta+.1 STEP .25
  390 X%=-W%*SIN Gamma:Y%=D%+H%*COS Gamma
  400 DRAW C*X%+S*Y%,C*Y%-S*X%
  410 NEXT
  420 ENDPROC
  430 DEF PROCp
  440 X%=1179:Y%=130:R%=100:Col%=9
  450 FOR Tilt=0 TO 1.2 STEP .05
  460 GCOL 0,Col%:PROCbox(X%,Y%,R%,Tilt)
  470 X%=.9*X%+80:Y%=.5*Y%+440:R%=R%*.92
  480 Col%=Col%+1:IF Col%=15 Col%=9
  490 NEXT
  500 ENDPROC
  510 DEF PROCbox(X%,Y%,R%,Tilt)
  520  VDU 29,X%;Y%;
  530 S=SIN Tilt:C=COS Tilt
  540 MOVE R%*(C+S),R%*(C-S)
  550 DRAW R%*(C-S),R%*(-C-S):DRAW R%*(-C-S),R%*(S-C)
  560 DRAW R%*(S-C),R%*(C+S):DRAW R%*(C+S),R%*(C-S)
  570 ENDPROC
  580 DEF PROCdots
  590 VDU 29,0;0;
  600 FOR I%=0 TO 40
  610 X%=1279:Y%=25*I%:X1%=-8*(2+RND(2)):Y1%=1-RND(3):Col%=RND(6)+8
  620 REPEAT Col%=Col%+1:IF Col%=15 Col%=9
  630 P%=POINT(X%,Y%):IF P%=0 GCOL 0,Col%:PLOT 69,X%,Y%
  640 X%=X%+X1%:Y%=Y%+Y1%
  650 UNTIL P%<0
  660 NEXT
  670 ENDPROC