1  REM Seek and Destroy
    2  REM By A.Weston
    3  REM July-August 1993
    4  REM Buy the Metallica song
    5  REM of the same name!
    6  REM **********************
   10 MODE7:VDU23;8202;0;0;0;:PRINTTAB(0,0);CHR$129;CHR$157;CHR$131;CHR$141;"SEEK AND DESTROY by A.J.W."
   20 PRINTTAB(0);CHR$129;CHR$157;CHR$131;CHR$141;"SEEK AND DESTROY by A.J.W."
   30 PRINT''"�<O> Thrust + <K> Thrust -"
   40 PRINT"�<Q> Bank left <W> Bank Right"
   41 PRINT"�<L> Up <P> Down"
   42 PRINT"�<G> Missile <SPACE> Fire"
   43 PRINT"�<ESCAPE> Eject"
   47  PRINT'"�Watch your shields and you"
   48 PRINT"�have 3 missiles. 11 kills to"
   49 PRINT"�complete."
   50 PRINT''"�<SPACE> to start":REPEATUNTILGET=32
   60 REM************INITIATE************
   70 ENVELOPE1,1,-1,-1,0,50,150,50,127,-1,-1,-1,0,0
   80 ENVELOPE2,4,0,0,0,0,0,0,10,-1,-1,-1,126,126
   90 ENVELOPE3,1,-1,0,0,255,0,0,127,-1,-1,-1,0,0
  100 DIM L(8)
  110 AA%=330:AB%=250
  120 MO%=0:ML%=4
  130 GT%=0
  140 SH%=40
  150 AB%=250
  160 X%=640:Y%=512
  170 PX%=700:PY%=Y%+50
  180 QX%=1:QY%=1
  190 FO%=0
  200 H%=0
  210 T=TIME
  220 P%=1
  230 GX%=640:GY%=512
  240 IF PX%<700ANDPX%>450AND QX%>=125 AND PY%<=600 AND PY%>=400 THEN PROCED
  250 Y2%=0:Y3%=0
  260 REM***MAIN PROGRAM***
  270 MODE5:VDU23;8202;0;0;0;
  280 *FX200,1
  290 *LOAD S.BSCR
  300 MOVE500,0:DRAW500,250:MOVE700,0:DRAW700,250:MOVE0,400:DRAW330,400:MOVE950,400:DRAW1280,400:MOVE0,600:DRAW330,600:MOVE950,600:DRAW1280,600
  310 GCOL0,2:MOVE330,250:DRAW330,780:DRAW950,780:DRAW 950,250:DRAW340,250
  320 VDU24,338;254;942;776;
  330 VDU19,1,2;0;
  340 VDU19,3,6;0;
  350 SOUND1,-8,170,-1
  360 SOUND0,-10,6,-1
  370 REPEAT
  380 IFINKEY(-17)THENY2%=Y2%+8:Y3%=Y3%-8:PX%=PX%+P%
  390 IFINKEY(-34)THENY2%=Y2%-8:Y3%=Y3%+8:PX%=PX%-P%
  400 IFINKEY(-55)THENP%=P%+1
  410 IFINKEY(-71)THENP%=P%-1
  420 IFINKEY(-87)THENY%=Y%-4:PY%=PY%-4
  430 IFINKEY(-56)THENY%=Y%+4:PY%=PY%+4
  440 IFINKEY(-113)THENVDU19,0,4;0;:PRINTTAB(5,1);"Ejected":GOSUB710
  450 IFINKEY(-84)ANDML%>0THENGOSUB1140
  460 IFINKEY(-99)THENMOVE400,255:GCOL0,3:DRAW640,512:DRAW800,255:GCOL0,0:MOVE400,255:DRAW640,512:DRAW800,255:FO%=1
  470 IFFO%=1 AND PX%>600 AND PX%<650 AND PY%>500 AND PY%<600THEN GOSUB760
  480 GCOL0,1
  490 MOVEX%,Y%:PLOT1,-300,Y2%:MOVEX%,Y%:PLOT1,300,Y3%
  500 GCOL0,2:PLOT69,X%,GY%:PLOT69,X%+24,GY%
  510 IFTIME-T>500THENGCOL0,2:MOVEPX%,PY%:PLOT1,-QX%,QY%:MOVEPX%,PY%:PLOT1,QX%,QY%:PLOT1,2*(-QX%),0
  520 IFMO%=1THENMOVEAA%,AB%:DRAWAA%+20,AB%+20
  530 FY%=RND(25):IFFY%=3THENGCOL0,3:MOVEPX%,PY%:DRAW640,512:FORW1%=1TO40:NEXTW1%:GCOL0,0:MOVEPX%,PY%:DRAW640,512:SH%=SH%-1:PRINTTAB(10,1);"Shields"SH%:IFSH%<0THENPROCED
  540 GCOL0,0:MOVEX%,Y%:PLOT1,-300,Y2%:MOVEX%,Y%:PLOT1,300,Y3%
  550 PLOT69,X%,GY%:PLOT69,X%+24,GY%
  560 MOVEPX%,PY%:PLOT1,-QX%,QY%:MOVEPX%,PY%:PLOT1,QX%,QY%:PLOT1,2*(-QX%),0
  570 IFMO%=1THENMOVEAA%,AB%:DRAWAA%+20,AB%+20
  580 IFY2%>250 THEN Y2%=250:Y3%=-250
  590 IFY3%>250 THEN Y3%=250:Y2%=-250
  600 GY%=GY%-P%
  610 IFGY%<=254 THENGY%=Y%
  620 IFGY%>Y%THENGY%=GY%-4
  630 IFP%<1THENP%=P%+1
  640 IFTIME-T>500 THEN QX%=QX%+P%/2:QY%=QY%+P%/2
  650 IF PX%>500ANDPX%<700  AND QX%>=125 AND PY%<=600 AND PY%>=400THENPROCED
  660 IF QX%>=125THENQX%=1:QY%=1:PX%=700:PY%=Y%+50:AA%=330:AB%=250:MO%=0
  670 IFAA%>=PX%THENPROCEX:MO%=0
  680 IFMO%=1THENAB%=AB%+8:AA%=AA%+8:IFAB%>PY%THENAB%=AB%-16
  690 IFGT%>10THENGOTO1220
  700 UNTILFALSE
  710 *FX15,0
  720 VDU19,3,6;0;
  730 SOUND 0,-15,7,50:SOUND1,3,1,50:REPEATUNTILGET=32
  740 RUN
  750 RETURN
  760 *FX21,4
  770 *FX21,5
  780 SOUND1,3,1,3:SOUND0,-15,7,3
  790 COLOUR2:PRINTTAB(1,1);"HITS ";H%
  800 FO%=0:H%=H%+1
  810 SOUND1,-8,170,-1:SOUND0,-10,6,-1
  820 IFH%>15THENPROCEX
  830 RETURN
  840 END
  850 DEF PROCEX
  860 *FX21,4
  870 *FX21,5
  880 VDU19,1,1;0;:GT%=GT%+1
  890 SOUND1,1,1,100:SOUND0,2,7,100
  900 FOREX%=1TO100
  910 GCOL0,RND(2)
  920 MOVEPX%,PY%:DRAWRND(1280),RND(1024)
  930 NEXTEX%
  940 PRINTTAB(1,1);"HITS   "
  950 COLOUR2:PRINTTAB(1,28);"Kills "GT%
  960 PX%=700:PY%=Y%+50:QX%=1:QY%=1
  970 VDU19,1,2;0;
  980 T=TIME
  990 SOUND1,-8,170,-1:SOUND0,-10,6,-1
 1000 AA%=330:AB%=250
 1010 CLG:H%=0:ENDPROC
 1020 DEF PROCED
 1030 CLS
 1040 *FX21,4
 1050 *FX21,5
 1060 FOREX2%=1TO10
 1070 VDU19,0,7;0;
 1080 SOUND0,-10,4,1
 1090 VDU19,0,0;0;
 1100 NEXTEX2%
 1105 IFSH%<=0THENCOLOUR1:PRINTTAB(1,1);"Shields destroyed"'"Aircraft also."ELSEVDU19,2,14;0;:COLOUR2:PRINTTAB(1,1);"Collision!":*FX9,5
 1106 *FX15,0
 1110 COLOUR1:PRINTTAB(1,25);"<SPACE>:new game":REPEATUNTILGET=32:RUN
 1120 ENDPROC
 1130 SOUND 0,-15,7,50:SOUND1,3,1,50
 1140 AA%=330:AB%=250
 1150 MO%=1:ML%=ML%-1
 1160 *FX21,4
 1170 *FX21,5
 1180 SOUND1,1,1,100:SOUND0,2,4,100
 1190 SOUND1,-8,170,-1:SOUND0,-10,6,-1
 1200 RETURN
 1210 REM*END*
 1220 *FO
 1230 *FX21,4
 1240 *FX21,5
 1250 MODE2
 1260 VDU23;8202;0;0;0;
 1270 *FX15,0
 1280 PROCFDR("All enemy aircraft",2)
 1290 PROCFDR("Now destroyed.",5)
 1300 PROCFDR("__________________",8)
 1310 PROCFDR("Thankyou for playing",11)
 1320 REPEAT:PROCFDR(" SEEK AND DESTROY ",14):IFINKEY(-99)THENGOTO1340
 1330 UNTILFALSE
 1340 RUN
 1350 DEF PROCFDR(T$,VP)
 1360 RESTORE1400
 1370 FORCO%=1TO8:READ L(CO%):NEXTCO%
 1380 FORFO%=1TO8:COLOUR L(FO%):PRINTTAB((20-LEN(T$))/2,VP);T$:T=TIME:REPEATUNTILTIME-T>5:NEXTFO%
 1390 FORFO2%=8TO1STEP-1:COLOUR L(FO2%):PRINTTAB((20-LEN(T$))/2,VP);T$:T=TIME:REPEATUNTILTIME-T>5:NEXTFO2%
 1400 DATA0,4,1,5,2,5,3,7
 1410 ENDPROC
 2000  REM***********************
 2010  REM*Yeah, I do still program
 2020  REM*on the BBC sometimes!
 2030  REM*In between going to work
 2040  REM*Listening to music,
 2050  REM*watching videos and going
 2060 REM*swimming,clubbing and reading
 2070 REM*science fiction and also
 2080 REM*Acorn Computing.See yer!
 2090 REM*Andrew Weston.
 3000 REM*Watch out for the Eddie demo
 3010 REM*-coming soon,hopefully!
 3020 REM****************************