10 DEFFNS="REP3CHT"
   20 IF PAGE<>&1900:PAGE=&1900:CHAIN"Rep3Cht"
   30 MODE7
   40 VDU23;80202;0;0;0;
   50 A%=0:X%=255:T%=USR&FFF4:T%=(T%DIV&100)AND7
   60 PRINT'TAB(3)"ƒREPTON 3 CHEAT by C.J.Richardson"
   70 PRINT''TAB(8)"��For 8-Bit Software"
   80 PRINTTAB(8)"ƒ�For 8-Bit Software"
   90 IF T%>2 PRINT''"‚BBC version Y/N?";
  100 IF T%>2 IF INSTR("Yy",GET$) T%=0:PRINT" Yes" ELSE IF T%>2 PRINT" No"
  110 Cheat1$="K.0MODE7:VDU23;8202;0;0;0;0:PAGE=&7900|MLO.""MV""|MDEL.10,50|MDEL.210,250|M105"
  120 Cheat2$="K.1 106"
  130 Cheat3$="K.2 107"
  140 Map%=0
  150 Lives%=0
  160 Immortal%=0
  170 Editor%=0
  180 Crowns%=0
  190 Diamonds%=0
  200 PRINT'"…See all maps Y/N?";
  210 IF INSTR("Yy",GET$) Cheat1$=Cheat1$+"?&304A=&D:":Map%=1:PRINT" Yes" ELSE PRINT " No"
  220 PRINT'"†Infinite Lives Y/N?";
  230 IF INSTR("Yy",GET$) Cheat1$=Cheat1$+"?&311C=&63:":Lives%=1:PRINT" Yes" ELSE PRINT" No"
  240 PRINT'"ƒImmortality Y/N?";
  250 IF INSTR("Yy",GET$) Cheat1$=Cheat1$+"?&1EBA=&EA:?&1EBB=&EA:?&2830=&EA:?&2831=&EA:?&2A85=&EA:?&2A86=&EA:?&6500=&EA:?&6501=&EA":Immortal%=1:PRINT" Yes" ELSE PRINT" No"
  260 Cheat1$=Cheat1$+"|M*FX138 0 129|M"
  270 IF Immortal%=1:Cheat2$=Cheat2$+"OSCLI""SRWRITE 6500+2 815A 5"":OSCLI""SRWRITE 6500+2 8197 5"":OSCLI""SRWRITE 6500+2 8218 5"":OSCLI""SRWRITE 6500+2 8298 5"":OSCLI""SRWRITE 6500+2 892E 5"":OSCLI""SRWRITE 6500+2 8954 5"":"
  280 IF T%>2 PRINT'"†No need for codes in editor Y/N?";:IF INSTR("Yy",GET$) Cheat2$=Cheat2$+"?&6502=&60:OSCLI""SRWRITE 6502+1 B17C 4""":PRINT" Yes" ELSE IF T%>2 PRINT" No"
  290 Cheat2$=Cheat2$+"|M*FX138 0 130|M"
  300 PRINT'"…No need to collect crowns Y/N?";
  310 IF INSTR("Yy",GET$) Cheat3$=Cheat3$+"?&2FF4=0:":Crowns%=1:PRINT" Yes" ELSE PRINT" No"
  320 PRINT'"‚No need to collect diamonds"'"‚or kill monsters Y/N?";
  330 IF INSTR("Yy",GET$) Cheat3$=Cheat3$+"?&2FED=0:":Diamonds%=1:PRINT" Yes" ELSE PRINT" No"
  340 Cheat3$=Cheat3$+"|MRUN|M"
  350 PRINT'TAB(3)"†INSERT REPTON DISC ˆPress a key"
  360 *FX21
  370 REPEATUNTILGET
  380 IF T%>2 PROCmaster
  390 MODE5
  400 FORI%=0TO2STEP2
  410 P%=&1100
  420 [:OPTI%:LDA#0:STA&606F
  430 LDA#inter MOD256:STA&220
  440 LDA#inter DIV256:STA&221
  450 LDA#14:LDX#4:JSR&FFF4
  460 RTS
  470 .inter:PHP:PHA:TXA:PHA:TXA:PHA:LDA&606F:CMP#&8C:BNEout
  480 LDA#7:JSR&FFEE:]
  490 IF Lives%=1 [:OPTI%:LDA#&63:STA&311C:]:REM LIVES. IF THIS DOESN'T WORK TRY &3119 INSTEAD OF &311C
  500 IF Map%=1 [:OPTI%:LDA#&D:STA&304A:]:REM SEE ALL MAPS. IF THIS DOESN'T WORK TRY &3052 INSTEAD OF &304A
  510 IF Immortal%=1 [:OPTI%:LDA#&EA:STA&55A:STA&55B:STA&597:STA&598:STA&618:STA&619:STA&698:STA&699:STA&1EBA:STA&1EBB:STA&2830:STA&2831:STA&2A85:STA&2A86:STA&5C3E:STA&5C3F:STA&5C64:STA&5C65:]:REM IMMORTALITY
  520 IF Crowns%=1 [:OPTI%:LDA#0:STA&2FF4:]:REM NO NEED FOR CROWN OR MONSTERS
  530 IF Diamonds%=1 [:OPTI%:LDA#0:STA&2FED:]:REM NO NEED TO COLLECT DIAMONDS
  540 [:OPTI%:LDA#13:LDX#4:JSR&FFF4
  550 .out:PLA:TAY:PLA:TAX:PLA:PLP:RTS
  560 ]:NEXT:CALL&1100
  570 *DIR D
  580 PAGE=&900:HIMEM=&C00:CHAIN"REPTON1"
  590 END
  600 DEFPROCmaster
  610 ENVELOPE1,1,0,0,0,0,0,0,126,-1,0,-1,126,0:ENVELOPE2,3,0,0,0,1,1,1,90,-20,-20,-2,90,0:ENVELOPE3,2,1,1,0,5,10,40,30,-10,-10,-15,127,0:ENVELOPE4,131,0,0,0,25,2,-2,110,0,-4,-8,110,80
  620 OSCLI Cheat1$
  630 OSCLI Cheat2$
  640 OSCLI Cheat3$
  650 *FX138 0 128
  660 END