10 REM >Input
   20 REM by Steven Flintham
   30 REM
   40 REM Friday 31st December 1993 (New Year's Eve)
   50 :
   60 MODE 7
   70 PROCdisable
   80 PROCinit
   90 PROCtitle
  100 PRINT'CHR$(131);"Please enter a string:";CHR$(135);
  110 string$=FNinput(10,FALSE)
  120 PRINT'CHR$(131);"You entered ";string$
  130 PROCenable
  140 END
  150 :
  160 DEF PROCdisable
  170 *FX229,1
  180 *FX4,1
  190 ENDPROC
  200 :
  210 DEF PROCenable
  220 *FX229
  230 *FX4
  240 ENDPROC
  250 :
  260 DEF PROCinit
  270 ON ERROR MODE 7:REPORT:PRINT " at line ";ERL:PROCenable:END
  280 ENDPROC
  290 :
  300 DEF PROCtitle
  310 VDU 26,12
  320 PRINTTAB(1,0);CHR$141;CHR$132;CHR$157;CHR$131;"Controlled input demonstration  ";CHR$156
  330 PRINTTAB(1,1);CHR$141;CHR$132;CHR$157;CHR$131;"Controlled input demonstration  ";CHR$156
  340 PRINTTAB(7,2);CHR$131;"(C) Steven Flintham 1993"
  350 ENDPROC
  360 :
  370 DEF FNinput(max%,null%)
  380 LOCAL text$,key%
  390 text$=""
  400 REPEAT
  410 REPEAT
  420 *FX21
  430 key%=GET
  440 UNTIL key%=13 OR (key%>=32 AND key%<=127)
  450 IF key%=127 AND LEN(text$)>0 THEN VDU 127:text$=LEFT$(text$,LEN(text$)-1)
  460 IF key%<>127 AND key%<>13 AND LEN(text$)<max% THEN VDU key%:text$=text$+CHR$(key%)
  470 UNTIL (key%=13 AND LEN(text$)>=ABS(NOT null%))
  480 =text$