10 REM ISSUE 32 VERSION BY C.J.Richardson for 8-Bit Software
   20 REM To create an ADFS version of the hints and tips disc
   30 REM Save Reed into DIR $
   40 REM *CDIR $.0
   50 REM *CDIR $.2
   60 REM *OPT 4 3
   70 REM*BUILD !BOOT   CHAIN"Reed" ESCAPE
   80 REM Copy hints 1 to 99 and INDEX0 to 5 into DIR 0
   90 REM Copy hints 100 to 206 into DIR 2
  100 DEFFNS="Reed"
  110 A%=0:Y%=0:SYS%=USR&FFDA MOD &100
  120 ONERROR VDU3:REPORT:PRINTERL:PRINT"Press a key to continue. E to end.":IF INSTR("Ee",GET$) END
  130 MODE3
  140 PRINT''"Printout of Hints and Tips."
  150 PRINT'"This program will display all of the hints files on BBC-24."''
  160 PRINT"1. View/Print All"
  170 PRINT"2. View All With Print Option on Each File"
  180 PRINT"3. Selective View/Printout"
  190 *FX21
  200 B$=GET$
  210 IF B$="3":PROCsel
  220 IFB$="1" PRINT'"To Printer Y/N?":IF INSTR("Yy",GET$):VDU2 ELSE PRINT'"Hold shift to scroll the text"':VDU14
  230 IF SYS%=8:OSCLI"DIR $.0" ELSE OSCLI"DR.0"
  240 REPEAT
  250 READ A$
  260 *FX21
  270 IF B$="2":VDU3:PRINT''"Printout of ";A$;"?"'':IF INSTR("Yy",GET$):VDU2
  280 IF SYS%=8:IF A$="100_102":*DIR $.2
  290 IF SYS%=4:IF A$="100_102":*DR.2
  300 REM PRINT''"*TYPEing ";A$''
  310 OSCLI"TYPE "+A$
  320 UNTIL A$="205_206"
  330 VDU3
  340 END
  350 DEFPROCsel
  360 REPEAT
  370 CLS
  380 *.
  390 PRINT'"Enter:"'"0. Change to directory/drive 0"
  400 PRINT"2. Change to directory/drive 2"
  410 PRINT"OR Enter filename to print"
  420 PRINT"Then press RETURN"
  430 *FX21
  440 INPUT A$
  450 IF LENA$=1:IF SYS%=8:OSCLI"DIR $."+A$
  460 IF LENA$=1:IF SYS%=4:OSCLI"DR."+A$
  470 *FX21
  480 IF LENA$<>1:PRINT"To Printer Y/N?":IF INSTR("Yy",GET$):VDU2 ELSE IF LENA$<>1:VDU14:PRINT'"PRESS SHIFT TO SCROLL TEXT"''
  490 IF LENA$<>1:OSCLI"TYPE "+A$
  500 VDU3,15
  510 IFLEN A$<>1:PRINT'"Press a key":REPEATUNTILGET
  520 UNTILFALSE
  530 DATAINDEX0,INDEX1,INDEX2,INDEX3,INDEX4,INDEX5
  540 DATA001_010,011_013,014_016,017_020,021_027,028_031,032_037,038_040,041_046,047_051,052_057,058_063,064_066,067_068,069_071,072_074,075_079,080_083,084_086,087_090
  550 DATA091_092,093_094,095_097,098_099,100_102,103_104,105_107,108_111,112_114,115_116,117_120,121_124,125_129,130_134,135_138,139_143,144_148,149_153,154_156,157_159,160_162,163_163,164_170,171_174,175_178,179_181,182_185
  560 DATA186_188,189_190,191_193,194_195,196_198,199_202,203_204,205_206