10 MODE1:VDU19,128,132;0;
   20 T$="      ELECTRIC APPLIANCE RATINGS"
   30 L$=STRING$(40,"_")  
   40 PRINTT$
   50 PRINTL$;"First, find your torch....":PRINT
   60 PRINT"This program calculates the power       consumption and running costs of any    electrical appliance. The only data you have to enter is the time your          electricity meter takes to make one or" 
   70 PRINT"more revs, first without the item you   want to rate, then with it. Just follow the program prompts. Timing 2 or 3 revs should be slightly more accurate than 1."
   80 PRINT"THIS PROGRAM ASSUMES THAT:              1)Your electricity meter revolves at      a rate of 112.5 revs/kWh - it           should say on the meter. If not,        adjust variable REVS appropriately."  
   90 PRINT:PRINT"2)Your electricity costs 7.27 p/unit.     If not, change variable PENCE to suit."
  100 PRINT"3)You have turned off any item which      uses power intermittently, such as a    fridge, which could confuse the         situation. ";
  110 PRINT"And don't blame me if you    forget to turn it back on and your ice  cream melts. Try a straw..."
  120 PRINT:PRINT"PRESS ANY KEY"
  130 A$=GET$
  140 ONERRORGOTO620
  150 MODE6:VDU19,0,4;0;
  160 REVS=112.5
  170 PENCE=7.27 
  180 Y=16
  190 F=3600/REVS
  200 PRINTT$
  210 PRINTL$
  220 PRINT:INPUT"WHICH ELECTRICAL ITEM",IT$;":"
  230 IF IT$=""THENIT$="APPLIANCE"
  240 CLS:PRINT"RATING AND RUNNING COSTS OF ";IT$;":"
  250 PRINTL$;"First enter timing without ";IT$;":"
  260 PRINT"(if meter stationary just press RETURN)"
  270 PRINT
  280 INPUT"NO. OF REVS",R1
  290 IFR1=0THENW1=0:PRINT:PRINT"EVERYTHING ELSE TURNED OFF":Y=13:GOTO420
  300 PRINT:PRINT"ENTER TOTAL TIME - MINS & SECS:"
  310 INPUT"MINS",M1
  320 INPUT"SECS",S1
  330 T1=M1*60+S1
  340 IF T1<=0THEN620
  350  PRINTTAB(0,7)"TOTAL TIME= ";M1;"min";S1;"sec.            "
  360 PRINTSTRING$(10," ")
  370 TR1=T1/R1
  380 W1=INT(1000*(F/TR1))
  390 PRINT"Rating without ";IT$;"= ";W1;" watts."
  400 C1=INT(PENCE*W1/10)/100
  410 PRINT"COST= ";C1;"p/hour or ";C1*24;"p/day."
  420 PRINTL$;"Now enter timing with ";IT$;":"
  430 PRINT
  440 INPUT"NO. OF REVS",R2
  450 PRINT:PRINT"ENTER TOTAL TIME - MINS & SECS:" 
  460 INPUT"MINS",M2
  470 INPUT"SECS",S2
  480  PRINTTAB(0,Y)"TOTAL TIME= ";M2;"min";S2;"sec.            "
  490 Y=16
  500 PRINTSTRING$(10," ")  
  510 T2=M2*60+S2
  520 TR2=T2/R2
  530 W2=INT(1000*(F/TR2))
  540 IFW2-W1<0THEN620
  550 PRINT"Rating of ";IT$;"= ";W2-W1;" watts." 
  560 C2=INT(PENCE*(W2-W1)/10)/100
  570  PRINT"COST= ";C2;"p/hour or ";C2*24;"p/day." 
  580 PRINTL$
  590 PRINT"PRESS: N FOR NEW RUN                           SPACE TO ESCAPE"
  600 A$=GET$:IF A$="N" THEN150
  610 END
  620 PRINTL$
  630 PRINT"A GLITCH HAS OCCURRED-PLEASE CHECK DATA"
  640 PRINT:PRINT"PRESS: R TO REPEAT                             SPACE TO ESCAPE"
  650 A$=GET$:IF A$="R"THEN240