10 REM TALK TO CHARLIE
   20 REM by Lorin Knight, Jan 1992
   25 REM revised Feb 19 1994
   30 ONERRORCHAIN"TALKtoC"
   35 *FX21,0
   40 *KEY10"OLD|MRUN|M"
   50 MODE7:*FX11,0
   60 DIMS%(51):FORN%=1TO51:S%(N%)=RND(50):NEXT:DIMA%(14):FORN%=1TO14:A%(N%)=N%:NEXT:N$="":BN$="":SN$=""
   70 oN$=N$:t%=0:PROCselect:PROCname:PROCrun:PROCq("THANK YOU FOR TALKING TO ME, "+N$):PROCq("IS THERE ANYONE ELSE WHO WOULD LIKE TO TALK TO ME?"):PROCr:IFLEFT$(A$,1)<>"N"GOTO70
   80 PROCq("CHEERIO, "+N$):*FX12,0
   90 END
  100 DEFPROCname:PRINT'':PROCq("HELLO.  I AM CHARLIE"):PROCq("WHAT IS YOUR NAME?"):PROCr:N$=FNn(A$):IFLENN$>15 N$=FNa(7):PROCq("I CAN'T SAY THAT"):PROCq("I WILL CALL YOU "+N$):ENDPROC
  110 IFN$=oN$PROCq("HELLO AGAIN, "+N$):ENDPROC
  120 IFN$=BN$PROCq("ARE YOU "+oN$+"'S BROTHER?"):PROCh
  130 IFN$=SN$PROCq("ARE YOU "+oN$+"'S SISTER?"):PROCh
  140 R%=RND(5):IFR%=1PROCq("I HAVE A "+FNa(1)+" CALLED "+N$)
  150 IFR%=2PROCq("I'M VERY PLEASED TO MEET YOU, "+N$)
  160 IFR%=3PROCq(N$+" IS A "+FNa(2)+" NAME")
  170 IFR%=4PROCq("I THINK THIS IS THE FIRST TIME WE HAVE MET, "+N$)
  180 IFR%=5PROCq("I WOULD LIKE TO KNOW A LITTLE MORE ABOUT YOU, "+N$)
  190 BN$="":SN$="":ENDPROC
  200 DEFPROCy:INPUT"  "Y$:IFLEFT$(Y$,1)="Y"ORLEFT$(Y$,1)="O"Y%=1ELSEY%=0
  210 ENDPROC
  220 DEFPROCh:PROCy:IFY%=1PROCq(oN$+" TOLD ME ABOUT YOU")ELSEPROCq("THAT MUST BE ANOTHER "+N$)
  230 ENDPROC
  240 DEFPROCold:IFA%>49ANDRND(3)=1PROCq("THAT IS VERY OLD"):ENDPROC
  250 IFA%<50ANDRND(3)=1PROCq("YOU ARE GETTING RATHER OLD, "+N$):ENDPROC
  260 IFRND(2)=1PROCq("THAT'S THE SAME AGE AS MY "+FNa(5))ELSEPROCq("YOU ARE NEARLY AS OLD AS MY "+FNa(5))
  270 ENDPROC 
  280 DEFPROChavnt:IFRND(2)=1PROCq(FNa(20)):ENDPROC
  290 IFRND(2)=1PROCq("MY "+FNa(3+RND(2))+" IS ALWAYS DOING IT"):PROCq(FNh+" IS "+FNa(14)):ENDPROC
  300 IFRND(2)=1PROCq("MY "+FNa(3+RND(2))+" DID"):PROCq(FNh+" HAD TO GO TO HOSPITAL")ELSEPROCq("YOU WON'T EVER DO IT IF YOU HAVE ANY SENSE")
  310 ENDPROC
  320 DEFPROChave:IFRND(4)=1PROCq("THAT'S A VERY FUNNY THING TO DO")
  330 IFRND(4)=1PROCq("DID EVERYBODY LAUGH?"):PROCy
  340 PROCq("YOU MUST BE "+FNa(14)):ENDPROC
  350 DEFPROCq(Z$):z$=RIGHT$(Z$,1):Z$=" "+Z$:PRINT:REPEATUNTILTIME>t%:REPEATT%=39:REPEATT%=T%-1:X$=MID$(Z$,T%,1):UNTILX$=" "ORX$="":PRINTCHR$130;LEFT$(Z$,T%-1):Z$=MID$(Z$,T%):UNTILLENZ$=0:t%=TIME+150
  360 IFz$="?"SOUND1,-10,50,3
  370 ENDPROC
  380 DEFPROCr:INPUT"  "A$:ENDPROC
  390 DEFPROCseason(A$):IFINSTR(A$,"MAR")>0ORINSTR(A$,"APR")>0ORINSTR(A$,"MAY")>0PROCq("I THINK IT'S RATHER NICE TO HAVE YOUR BIRTHDAY IN THE SPRING"):ENDPROC
  400 IFINSTR(A$,"JUN")>0ORINSTR(A$,"JUL")>0ORINSTR(A$,"AUG")>0PROCq("IT MUST BE LOVELY TO HAVE YOUR BIRTHDAY IN THE SUMMER"):ENDPROC
  410 PROCq("THAT'S QUITE A NICE TIME TO HAVE A BIRTHDAY"):ENDPROC
  420 DEFPROCparty:PROCq("WILL YOU HAVE A BIRTHDAY PARTY?"):PROCy:IFY%=0GOTO490
  430 IFRND(6)=1PROCq("CAN I COME?"):GOTO450
  440 IFRND(3)=1PROCq("WILL YOU SAVE ME A "+FNa(38)+", "+N$+"?")ELSEGOTO460
  450 PROCy:IFY%=1PROCq("THANK YOU VERY MUCH, "+N$)ELSEPROCq("A PITY"):ENDPROC
  460 PROCq("HOW MANY PEOPLE WILL YOU INVITE"):INPUT"  "A%:IFA%<4PROCq("SO IT WILL ONLY BE A SMALL PARTY"):GOTO490
  470 IFA%>12PROCq(FNa(39)):ENDPROC
  480 PROCq(FNa(40)):ENDPROC
  490 IFRND(3)=1PROCq("A PITY. I WOULD HAVE LIKED TO COME"):ENDPROC
  500 PROCq("I LIKE TO GO TO "+FNa(41)+" ON MY BIRTHDAY"):ENDPROC
  510 DEFPROCselect:FORN%=1TO5:E%=RND(10-N%):D%=A%(E%):A%(E%)=A%(10-N%):A%(10-N%)=A%(15-N%):A%(15-N%)=D%:NEXT:ENDPROC
  520 DEFPROCrun:FORO%=10TO14:GOSUB(1900+100*A%(O%)):NEXT:ENDPROC
  530 PROCr:PROCq(FNa(22,9)):ENDPROC
  540 DEFPROCpet:PROCq("I HAVE A PET TIGER"):PROCq("I CALL HIM TIMMY"):ENDPROC
  550 DEFFNa(J%):RESTORE(5000+J%):READK%:C%=(S%(J%)+RND(3))MODK%:S%(J%)=C%:FORN%=0TOC%:READB$:NEXT:=B$
  560 DEFFNh:IFC%MOD2=0="HE"ELSE="SHE"
  570 DEFFNc:IFRND(3)=1="A SORT OF "+FNa(27)+" "+FNa(28)ELSE=FNa(28)
  580 DEFFNn(X$):I%=INSTR(X$," "):IFI%=0=X$ELSE=LEFT$(X$,I%-1)
  590 DEFFNb(A$):L%=LENA$:B$="":FORN%=1TOL%:D$=MID$(A$,N%,1):IFASC(D$)>47ANDASC(D$)<58 B$=B$+D$
  600 NEXT:=VAL(B$)
 2000 PROCq("HOW OLD ARE YOU, "+N$+"?"):PROCr:A%=FNb(A$):IFA%>99PROCq("DON'T BE SILLY. YOU ARE NOT AS OLD AS THAT"):RETURN
 2010 IFA%=0PROCq("THAT'S THE SAME AGE AS MY UNCLE'S ELEPHANT"):RETURN
 2020 IFA%>35PROCold:RETURN
 2030 IFA%<4PROCq("NOT MANY "+STR$(A%)+"-YEAR-OLDS CAN OPERATE A COMPUTER"):RETURN
 2040 IFRND(4)=1PROCq("THAT'S A VERY NICE AGE TO BE"):RETURN
 2050 IFRND(2)=1PROCq("THAT'S THE SAME AGE AS MY "+FNa(4)):RETURN 
 2060 PROCq("MY "+FNa(1)+" IS "+STR$(A%)+" TOO"):RETURN
 2100 PROCq("WHEN IS YOUR BIRTHDAY, "+N$+"?"):PROCr:IFINSTR(A$,"DEC")>0ANDINSTR(A$,"25")>0PROCq("OH, I DON'T THINK I WOULD WANT MY BIRTHDAY TO BE ON CHRISTMAS DAY"):GOTO2150
 2110 IFINSTR(A$,"DEC")>0ANDINSTR(A$,"26")>0PROCq("OH, I DON'T THINK I WOULD WANT MY BIRTHDAY TO BE ON BOXING DAY"):GOTO2150
 2115 IFINSTR(A$,"TODA")+INSTR(A$,"TOMO")>0PROCq("HAPPY BIRTHDAY, "+N$):PROCq("I HOPE YOU HAVE A VERY HAPPY DAY"):GOTO2150
 2120 IFRND(3)=1PROCseason(A$):GOTO2150
 2130 IFRND(4)=1PROCq("THAT'S JUST AFTER MY "+FNa(1)+"'S BIRTHDAY"):GOTO2150
 2140 PROCq("THAT'S MY "+FNa(3+RND(2))+"'S BIRTHDAY TOO")
 2150 IFRND(3)=1PROCparty
 2160 RETURN
 2200 PROCq("DO YOU LIKE DOING SUMS?"):PROCy:IFY%=1GOTO2240
 2210 IFRND(4)=1PROCq("THEN I WON'T GIVE YOU ANY"):RETURN
 2220 IFRND(2)=1PROCq("I EXPECT YOU WOULD RATHER PLAY "+FNa(19)):RETURN
 2230 PROCq("I LOVE THEM"):PROCq("I OFTEN DO "+STR$(10+RND(70))+" BEFORE BREAKFAST"):RETURN
 2240 F%=2:G%=4:I%=0:FORN%=1TO4:F%=F%+RND(3):G%=2*N%+RND(3):PROCq("WHAT IS "+STR$F%+" + "+STR$G%+"?"):INPUT"  "H%
 2250 IFH%=F%+G%PROCq("CORRECT!"):I%=I%+1:ELSEPROCq("SORRY!  "+STR$F%+" + "+STR$G%+" = "+STR$(F%+G%))
 2260 NEXT
 2265 IFI%>3PROCq("VERY GOOD, "+N$):PROCq("YOU GOT EVERY ONE RIGHT"):RETURN
 2270 IFI%=0PROCq("OH DEAR, "+N$+". YOU GOT THEM ALL WRONG")ELSEPROCq("YOU GOT "+STR$I%+" RIGHT OUT OF 4")
 2280 IFI%<3PROCq("PERHAPS THEY WERE TOO HARD FOR YOU")
 2290 RETURN
 2300 PROCq("CAN YOU "+FNa(49)+"?"):PROCy:IFY%=1ANDC%=4PROCq("C'EST TRES BON, "+N$):PROCq("JE PARLE FRANCAIS TRES BIEN"):PROCq("MON PERE EST FRANCAIS"):RETURN
 2310 IFY%=0GOTO2360
 2320 IFRND(2)=1PROCq("YOU ARE VERY CLEVER")ELSEPROCq("I WISH I COULD")
 2330 IFRND(3)=1PROCq("I HAVE TRIED AND TRIED"):GOTO2350
 2340 IFRND(2)=1PROCq("MY "+FNa(3+RND(2))+" TRIED TO TEACH ME")ELSEPROCq("MY "+FNa(3+RND(2))+" DOES IT ALL THE TIME")
 2350 PROCq("BUT I "+FNa(15)):RETURN
 2360 IFRND(2)=1PROCq("IT'S QUITE EASY")ELSEPROCq("I'M QUITE GOOD AT IT")
 2370 IFRND(3)=1PROCq("SOMETIMES I DO IT WHEN I GO TO SEE MY "+FNa(4)):GOTO2385
 2380 IFRND(2)=1PROCq("MY "+FNa(4)+" TAUGHT ME")ELSEPROCq("I LEARNT HOW TO DO IT WHEN I WENT TO "+FNa(9))
 2385 IFRND(3)=1PROCq("BUT I DON'T DO IT VERY OFTEN"):PROCq(FNa(12))
 2390 RETURN
 2400 PROCq("WHAT COLOUR IS YOUR HAIR?"):PROCr:IFLENA$>9PROCq("THAT'S RATHER UNUSUAL"):GOTO2420
 2410 IFRND(2)=1PROCq("IT MUST LOOK RATHER "+FNa(42)):RETURN
 2420 PROCq("MY HAIR IS "+FNc):IFRND(3)=1PROCq("WITH STREAKS OF "+FNa(28))
 2430 RETURN
 2500 PROCq("DO YOU HAVE A BROTHER?"):PROCy:IFY%=1PROCq("WHAT IS HIS NAME?"):PROCr:BN$=FNn(A$):ELSEBN$=""
 2510 IFLENBN$>15PROCq("THAT'S A VERY UNUSUAL NAME"):BN$="HE"
 2520 IFBN$=""GOTO2540
 2530 PROCq("DOES "+BN$+" "+FNa(32)+"?"):PROCy:IFY%=1PROCq(FNa(36))ELSEPROCq(FNa(35))
 2540 PROCq("DO YOU HAVE A SISTER?"):PROCy:IFY%=1PROCq("WHAT IS HER NAME?"):PROCr:SN$=FNn(A$):ELSESN$=""
 2550 IFSN$=""GOTO2565
 2555 IFLENSN$>15PROCq("I'VE NEVER HEARD THAT NAME BEFORE"):SN$="SHE"
 2560 PROCq("DOES "+SN$+" "+FNa(32)+"?"):PROCy:IFY%=1PROCq(FNa(3))ELSEPROCq(FNa(37))
 2565 IFBN$<>""ORSN$<>""RETURN
 2570 PROCq("DO YOU HAVE A DOG?"):PROCy:IFY%=1PROCpet:RETURN
 2575 PROCq("DO YOU HAVE A CAT?"):PROCy:IFY%=1PROCpet:RETURN
 2580 PROCq("DO YOU HAVE A BUDGIE?"):PROCy:IFY%=1PROCpet ELSEPROCq("YOUR HOUSE MUST BE VERY QUIET")
 2590 RETURN
 2600 PROCq("WHERE DO YOU LIVE?"):PROCr:B$=LEFT$(A$,3):IFB$="IN "ORB$="ON "ORB$="UP "PROCq("MY "+FNa(3+RND(2))+" LIVES "+A$):PROCq(FNh+" KEEPS "+FNa(16)):RETURN
 2605 IFLENA$>30GOTO2650
 2606 IFLENA$>14ANDINSTR(A$," ")=0GOTO2650
 2610 IFRND(4)=1PROCq("I LIVE QUITE NEAR THERE"):PROCq("NEXT TO THE "+FNa(17)):RETURN
 2615 IFRND(2)=1GOTO2630
 2620 PROCq("YOU MUST LIVE SOMEWHERE NEAR MY "+FNa(3+RND(2))):PROCq(FNh+" LIVES BEHIND THE "+FNa(17)):IFRND(2)=1PROCq("AND KEEPS "+FNa(16))
 2625 RETURN
 2630 PROCq("DO YOU GET ANY "+FNa(13)+" IN YOUR GARDEN?"):PROCy:IFY%=1PROCq("SO DO I")ELSEPROCq("I DO")
 2640 PROCq(FNa(47)):RETURN
 2650 PROCq("I DON'T KNOW WHERE THAT IS"):PROCq("IS IT IN "+FNa(9)+"?"):PROCy
 2660 IFY%=1PROCq("I THOUGHT IT MUST BE")ELSEPROCq("WHERE IS IT THEN?"):PROCr:PROCq("I DIDN'T KNOW THAT")
 2670 RETURN
 2700 PROCq("DO YOU LIKE "+FNa(24)+", "+N$+"?"):PROCy:IFY%=0PROCq("I LOVE THEM"):PROCq(FNa(25)):RETURN
 2710 PROCq("I HATE THEM"):PROCq(FNa(26)):IFRND(3)=1PROCq("MY "+FNa(4)+" ALWAYS HAS THEM FOR SUNDAY TEA")
 2720 RETURN
 2800 PROCq("WHAT IS YOUR FAVOURITE COLOUR?"):PROCr:IFLENA$<15GOTO2830
 2810 A$="THAT COLOUR":PROCq("I DON'T KNOW WHAT "+A$+" IS LIKE"):H%=0:REPEATH%=H%+1:PROCq("IS IT A SORT OF "+FNa(27)+" "+FNa(28)+"?"):PROCy:UNTILY%=1ORH%=3
 2820 IFY%=0PROCq("IT MUST BE A VERY UNUSUAL COLOUR"):RETURN:ELSEPROCq("I DON'T THINK I WOULD LIKE IT"):RETURN
 2830 IFRND(3)<3GOTO2841
 2831 PROCq("I DON'T LIKE "+A$+" VERY MUCH"):PROCq("I HAVE SOME "+A$+" "+FNa(31)):IFRND(2)=1PROCq("BUT I NEVER WEAR THEM")ELSEPROCq("AND I HATE THEM")
 2838 RETURN
 2841 IFRND(2)=1REPEATC$=FNa(28):UNTILC$<>A$:PROCq("THAT USED TO BE MY FAVOURITE COLOUR"):PROCq("BUT NOW IT'S "+C$):RETURN
 2850 IFC%<15PROCq("DO YOU HAVE ANY "+A$+" "+FNa(31)+"?")ELSEPROCq("DO YOU HAVE ANY "+FNa(31)+" THAT COLOUR?")
 2860 PROCy:IFY%=1PROCq(FNa(29))ELSEPROCq(FNa(30))
 2870 RETURN
 2900 PROCq("DO YOU LIKE READING BOOKS?"):PROCy:IFY%=1GOTO2930
 2910 PROCq("I LOVE BOOKS"):IFRND(4)=1PROCq("SOMETIMES I READ "+STR$(3+RND(30))+" IN ONE DAY"):RETURN
 2920 PROCq("I LIKE READING "+FNa(8)):RETURN
 2930 PROCq("TELL ME THE NAME OF A BOOK YOU LIKE"):PROCr:IFRND(3)=1PROCq("YES, I LIKE THAT ONE TOO"):PROCq(FNa(43)):RETURN
 2940 H%=0:REPEATH%=H%+1:PROCq("IS IT THE ONE ABOUT THE "+FNa(44)+" AND THE "+FNa(45)+"?"):PROCy:UNTILY%=1ORH%=3:IFY%=0PROCq("I DON'T THINK I HAVE READ IT"):RETURN
 2950 PROCq(FNa(46)):RETURN
 3000 PROCq("DO YOU LIKE PLAYING "+FNa(19)+", "+N$+"?"):PROCy:IFY%=1PROCq("SO DO I"):PROCq(FNa(21)):ELSEPROCq("NOR DO I"):PROCq(FNa(48))
 3010 RETURN
 3100 PROCq("DO YOU LIKE WATCHING "+FNa(18)+" ON THE TELEVISION?"):PROCy:IFY%=1 PROCq("WHAT ELSE DO YOU LIKE WATCHING?")ELSEPROCq("WHAT DO YOU LIKE WATCHING?")
 3110 PROCr:PROCq(FNa(22)):RETURN
 3200 IFRND(2)=1GOTO3230
 3210 PROCq("HAVE YOU EVER "+FNa(10)+"?"):PROCy:IFY%=1PROChave ELSEPROChavnt
 3220 RETURN
 3230 PROCq("HAVE YOU EVER BEEN TO "+FNa(9)+"?"):PROCy:IFY%=1ANDRND(2)=1PROCq("DID YOU LIKE IT THERE?"):PROCy
 3235 IFRND(2)=1GOTO3260
 3240 IFRND(2)=1PROCq("I WENT THERE FOR A HOLIDAY ONCE")ELSEPROCq("MY "+FNa(5)+" TOOK ME THERE LAST YEAR")
 3250 PROCq(FNa(6)):RETURN
 3260 IFRND(2)=1PROCq("I AM GOING THERE FOR A HOLIDAY NEXT YEAR")ELSEPROCq("I HOPE TO GO THERE ONE DAY")
 3270 PROCq("MY "+FNa(5)+" "+FNa(11)):RETURN
 3300 PROCq("WHAT COLOUR ARE YOUR EYES?"):PROCr:IFLENA$>9PROCq("NOT MANY PEOPLE HAVE EYES THAT COLOUR"):GOTO3350
 3310 IFA$="GREEN"ANDRND(3)=1PROCq("MY CAT HAS GREEN EYES"):PROCq("THEY SHINE IN THE DARK"):GOTO3330
 3320 IFRND(3)=1PROCq("MY "+FNa(3+RND(2))+" HAS "+A$+" EYES"):GOTO3350
 3330 IFRND(2)=1PROCq("I THINK "+A$+" EYES ARE VERY "+FNa(42)):GOTO3350
 3340 PROCq("DO YOU HAVE "+A$+" "+FNa(31)+" TO MATCH?"):PROCy:IFLEFT$(Y$,1)="Y"PROCq("HOW LOVELY")ELSEPROCq("WHAT A PITY")
 3350 IFRND(4)=1PROCq("MY EYES ARE "+FNc)
 3360 RETURN
 5001 DATA8,DOG,CAT,HAMSTER,GOLDFISH,DUCK,GOOSE,PET TIGER,PARROT
 5002 DATA7,FUNNY,VERY NICE,GOOD,JOLLY GOOD,LOVELY,RATHER SILLY,BEAUTIFUL
 5003 DATA5,SO DOES MY SISTER,SHE DOESN'T SEEM TO BE A VERY NICE GIRL,I EXPECT THAT MAKES YOU CROSS,THAT'S NOT VERY NICE,I DON'T SUPPOSE YOU LIKE THAT
 5004 DATA8,FRIEND SPOTTY SMITH,GIRL FRIEND,COUSIN MARMADUKE,COUSIN ALICE,COUSIN JACK,FRIEND SMELLY NELLY,FRIEND DICKY BIRD,COUSIN MARY JANE
 5005 DATA8,UNCLE TOM,GRANNY,UNCLE BOB,AUNTY BETTY,GRANDPA,AUNTY BESSIE,FRIEND MR BLOBBY,MUSIC TEACHER
 5006 DATA4,I DIDN'T LIKE THE FOOD,IT RAINED ALL THE TIME,AND I CAUGHT CHICKENPOX,AND I BROKE MY ARM 
 5007 DATA6,BESSY,NODDY,JIMBO,FRED,SILLY-BILLY,WALLY 
 5008 DATA6,IN THE BATH,WINNIE THE POOH,BOOKS WITH PICTURES,STORIES ABOUT DRAGONS,GHOST STORIES,IN BED
 5009 DATA9,AMERICA,CHINA,AFRICA,FRANCE,ITALY,CANADA,HONG KONG,SPAIN,INDIA
 5010 DATA8,POKED A LION IN THE EAR,KNOCKED A KETTLE OF HOT WATER OVER YOURSELF,JUMPED OFF THE ROOF,PUT ICE CREAM IN YOUR EARS,SAT ON A LIGHTED CANDLE,SWALLOWED A SPIDER,PUSHED A CHERRY UP YOUR NOSE,PUT YOUR HAND INSIDE A WASP NEST
 5011 DATA4,IS GOING TO TAKE ME,HAS A HOUSE BY THE SEA THERE,HAS A FRIEND WHO LIVES THERE,LIVES THERE,GOES THERE EVERY YEAR FOR A HOLIDAY
 5012 DATA4,IT MAKES THE DOG BARK,PEOPLE LAUGH AT ME,IT MAKES ME VERY TIRED,THE LAST TIME WAS ON AUNTY NELLY'S BIRTHDAY
 5013 DATA6,SQUIRRELS,ROBINS,BLACKBIRDS,RABBITS,HEDGEHOGS,DUCKS
 5014 DATA6,A BIT OF A WALLY,CRAZY,RATHER STUPID,A VERY SILLY PERSON,AS MAD AS A HATTER,POTTY
 5015 DATA3,AM HOPELESS,CAN'T DO IT,AM NO GOOD AT IT
 5016 DATA7,ELEPHANTS,CAMELS,DONKEYS,GIRAFFES,LIONS,LOTS OF GOATS,CROCODILES
 5017 DATA8,POST OFFICE,HOSPITAL,LIBRARY,SWIMMING POOL,BIG HOTEL,MARKET,FOOTBALL GROUND,PARK
 5018 DATA11,POSTMAN PAT,TOM AND JERRY,JACKANORY,SUPERTED,PLAYDAYS,SESAME STREET,SCOOBY DOO,GARFIELD,THE MAGIC ROUNDABOUT,BLUE PETER,THOMAS THE TANK ENGINE
 5019 DATA11,FOOTBALL,CRICKET,TIDDLY-WINKS,NETBALL,DOMINOES,SNAKES AND LADDERS,DOCTORS AND NURSES,LUDO,SNAP,THE PIANO,HIDE AND SEEK
 5020 DATA4,I'M GLAD TO HEAR IT,GOOD FOR YOU,I'M PLEASED TO HEAR THAT YOU HAVE MORE SENSE,NOR HAVE I - AND I DON'T WANT TO EITHER
 5021 DATA8,I'M A WORLD CHAMPION,IT'S GOOD FUN,I LIKE PLAYING IT UNDER WATER,ESPECIALLY WHEN IT IS RAINING,BUT I DON'T PLAY IT MUCH,I LOVE IT,BUT I'M NOT VERY GOOD AT IT,I PLAY IT EVERY SUNDAY MORNING
 5022 DATA9,MY SISTER WATCHES IT BUT I THINK IT'S SILLY,IT'S HORRID,I THINK THAT IS VERY FUNNY,MY BROTHER HATES IT. HE TURNS THE TELEVISION OFF WHEN IT COMES ON,I DON'T LIKE THAT,I THINK IT'S STUPID,I WATCH THAT EVERY TIME ITS ON
 5023 DATAI HAVE NEVER SEEN THAT,THAT'S ONE OF MY FAVOURITES
 5024 DATA11,TOMATOES,BANANAS,GREEN PEPPERS,STRAWBERRIES,POLO MINTS,MARS BARS,ONIONS,FRIED SNAILS,FISH FINGERS,SEAWEED SANDWICHES,FROG PIES
 5025 DATA8,I EAT THEM WITH CUSTARD,I HAVE THEM FOR SUNDAY DINNER,ESPECIALLY WITH TOMATO SAUCE,THEY ARE LOVELY WITH CHOCOLATE ICE CREAM,I CAN'T THINK WHY YOU DON'T LIKE THEM,YUM YUM YUM,I PUT MARMALADE ON THEM,WE OFTEN HAVE THEM FOR SUPPER
 5026 DATA7,THEY MAKE ME SICK,THEY GIVE ME TUMMY ACHE,THEY ARE HORRIBLE,I DON'T LIKE THE SMELL OF THEM,THEY GIVE ME BAD DREAMS,THEY ARE REVOLTING,THEY MAKE ME SNEEZE
 5027 DATA7,SILVERY,CREAMY,FUNNY,DARK,DIRTY,PALE,YUCKY
 5028 DATA12,BROWN,PINK,GREEN,BLUE,YELLOW,RED,ORANGE,SKY BLUE PINK,BLACK,GREY,WHITE,VIOLET
 5029 DATA5,HOW HORRID,THEY MUST LOOK VERY PRETTY,I EXPECT THEY FRIGHTEN THE CATS,I SUPPOSE YOU KEEP THEM FOR SUNDAYS,HOW LOVELY
 5030 DATA4,WHAT A PITY - IT'S A NICE COLOUR,THAT'S A SHAME. YOU WOULD LOOK PRETTY IN THEM,PERHAPS YOU WILL GET SOME FOR YOUR BIRTHDAY,PERHAPS SANTA CLAUS WILL BRING YOU SOME FOR CHRISTMAS
 5031 DATA8,SOCKS,SHOES,TEE SHIRTS,TROUSERS,JUMPERS,GLOVES,JEANS,WELLIES
 5032 DATA10,TEASE YOU,HIT YOU,PLAY TRICKS ON YOU,PUT FROGS IN YOUR BED,PULL YOUR HAIR,BREAK YOUR TOYS,HIDE YOUR SOCKS,EAT ALL YOUR SMARTIES,PUT DEAD FLIES IN YOUR CORNFLAKES,BREAK YOUR PENCILS
 5033 DATATIE KNOTS IN YOUR SHOE LACES,PUT ICE CREAM DOWN YOUR BACK,FIGHT WITH YOU,PUT JAM IN YOUR SHOES,POUR CUSTARD OVER YOUR HEAD,PLAY VERY LOAD MUSIC ALL DAY LONG
 5034 DATA4,HE MUST BE QUITE A KIND BOY,I THINK I WOULD LIKE HIM,I'M PLEASED TO HEAR THAT,HE SEEMS TO BE NICER THAN MY BROTHER
 5035 DATA6,HE SEEMS TO BE QUITE A NICE BOY,I THINK I WOULD LIKE HIM,MY BROTHER IS ALWAYS DOING IT,HE SEEMS TO BE NICER THAN MY BROTHER,I EXPECT YOU ARE PLEASED ABOUT THAT,I'M GLAD TO HEAR THAT
 5036 DATA5,SO DOES MY BROTHER,HE DOESN'T SEEM TO BE A VERY NICE BOY,I EXPECT THAT MAKES YOU CROSS,THAT'S NOT VERY NICE,HOW HORRID
 5037 DATA6,SHE SEEMS TO BE QUITE A NICE GIRL,I THINK I WOULD LIKE HER,MY SISTER IS ALWAYS DOING IT,SHE SEEMS TO BE NICER THAN MY SISTER,I EXPECT YOU ARE PLEASED ABOUT THAT,I'M GLAD TO HEAR THAT
 5038 DATA3,PIECE OF CAKE,BALLOON,SAUSAGE ROLL
 5039 DATA3,THAT'S QUITE A CROWD,I THINK YOUR HOUSE WILL BE FULL,WHAT A LOT!
 5040 DATA3,THAT WILL BE FUN,THAT'S A GOOD NUMBER FOR A PARTY,I SHALL HAVE 13 PEOPLE TO MINE
 5041 DATA5,THE ZOO,THE PARK,AUNTIE BETTY'S,McDONALD'S,THE SWIMMING POOL
 5042 DATA4,BEAUTIFUL,LOVELY,PRETTY,ATTRACTIVE
 5043 DATA5,ESPECIALLY THE PICTURES,IT'S AN EXCITING STORY,IT'S VERY FUNNY,EXCEPT FOR THE ENDING,BUT IT'S RATHER SAD
 5044 DATA17,BEAR,PRINCESS,WICKED WITCH,NAUGHTY PUPPY,WHITE RABBIT,KITTEN,GOOSE GIRL,PARROT,HORRID QUEEN,ICE CREAM MAN,MOUSE,SNOWMAN,SCARECROW,FRIENDLY GIANT,CROCODILE,LITTLE RED HEN,PIRATE
 5045 DATA17,FROG THAT TURNED INTO A PRINCE,DRAGON,WOLF,BALLOON,SPACE SHIP,TURTLES,UGLY SISTERS,FAIRY GODMOTHER,DWARFS,CAT WITH A WOODEN LEG,MAGIC CRICKET BAT,BURIED TREASURE,LOST SHEEP,FIRE ENGINE,RED SHOES,THREE FOXES,CHRISTMAS PUDDING
 5046 DATA4,I LIKE THAT ONE,I THOUGHT IT WAS BORING,I DIDN'T LIKE THAT ONE,I THOUGHT IT HAD A FUNNY ENDING
 5047 DATA5,LOTS OF THEM,I GIVE THEM PIECES OF BREAD,TWO OF THEM COME EVERY MORNING,BUT THE DOG CHASES THEM AWAY,AND TWO BIG BLACK CATS
 5048 DATA7,IT'S RATHER BORING,I'M NO GOOD AT IT,IT MAKES MY FEET HURT,I NEVER PLAY IT,I HATE IT,I PREFER HORSE-RIDING,IT GIVES ME HEADACHES
 5049 DATA8,RIDE A BICYCLE,STAND ON YOUR HEAD,WALK ON YOUR HANDS,DO CARTWHEELS,SPEAK FRENCH,WIGGLE YOUR EARS,PLAY THE TRUMPET,PLAY THE VIOLIN