100 code%=C%:store%=S%:main=code%+&9C:adr=&70:len=&76:dots=&77
  110 DIM X%(25),Y%(25),apeX%(25),apeY%(25)
  120 MODE 7:PROCheader:PROCgetparams
  130 MODE 0:HIMEM=&2C00
  140 VDU 2:*FX3,64
  150 FOR loop%=1 TO LEN(M$):CLS
  160 let$=MID$(M$,loop%,1):PROCdrawletter(let$)
  170 IF let$<>" " PROCdumpletter
  180 NEXT:VDU 3,7:END
  190 :
 1000 DEF PROCheader
 1010 FOR I%=0 TO 1
 1020 VDU 157,129,141:PRINT"  SPLINETEXT V1.1 by David James"
 1030 NEXT:VDU 31,0,24,157,129:PRINTSPC10"(C) BEEBUG 1990";:VDU 28,0,23,39,2
 1040 ENDPROC
 1050 :
 1060 DEF PROCgetparams
 1070 REPEAT PRINT'" Your message ";
 1080 INPUT LINE M$:UNTIL LEN(M$)>0
 1090 REPEAT PRINT'" Width of letters (inches) :";
 1100 INPUT "" xsize:UNTIL xsize>0
 1110 REPEAT PRINT'" Height of letters (inches) :";
 1120 INPUT "" ysize:UNTIL ysize>0
 1160 IF xsize>7.1111 xsize=7.1111
 1170 IF xsize<=(32/9) THEN xdpp=2
 1180 IF xsize<=(16/9) THEN xdpp=1
 1190 ydpp=3:IF ysize>8 ysize=8
 1200 IF ysize<=(16/3) THEN ydpp=2
 1210 IF ysize<=(8/3) THEN ydpp=1
 1220 ysc=(ysize/ydpp)*1279*3/(8*28)
 1230 ENDPROC
 1240 :
 1250 DEF PROCscalex
 1260 xs=xsize:realx=xs*xmax/29
 1270 adjx=INT(0.5+realx*9)/9
 1280 xs=(adjx*xs)/realx
 1290 xsc=(1024*xs*9)/(16*xdpp*29)
 1300 xsc=(xmax*xsc-4)/xmax
 1310 ENDPROC
 1320 :
 1330 DEF PROCdrawletter(letter$)
 1340 IF letter$=" " THEN PROCls(108*xsize):ENDPROC
 1350 RESTORE (2610+10*(INSTR("ABCDEFGHIJKLMNOPQRSTUVWXYZ.!,",letter$)))
 1360 READ S$,fill$
 1370 XS=FNt(1):YS=FNt(2):xmax=FNt(3)
 1380 PROCscalex
 1390 REPEAT READ N$
 1400 IF N$<>"E" READ S$:L%=(LENS$)/2
 1410 IF N$="S" PROCspline ELSE IF N$="L" PROCline
 1420 UNTIL N$="E"
 1440 ENDPROC
 1450 :
 1460 DEF PROCline
 1470 PROCline1(0,1,0,1)
 1480 IF XS<>0 PROCline1(2*XS,-1,0,1)
 1490 IF YS<>0 PROCline1(0,1,2*YS,-1)
 1500 IF XS<>0 AND YS<>0 PROCline1(2*XS,-1,2*YS,-1)
 1510 ENDPROC
 1520 :
 1530 DEF PROCline1(xc,xm,yc,ym)
 1540 x=FNd(1,xc,xm):y=FNd(2,yc,ym)
 1550 MOVE FNy(y),FNx(x)
 1560 FOR N%=1 TO L%-1
 1570 x=FNd(1+2*N%,xc,xm)
 1580 y=FNd(2*(N%+1),yc,ym)
 1590 DRAW FNy(y),FNx(x)
 1600 NEXT N%
 1610 ENDPROC
 1620 :
 1630 DEF PROCspline
 1640 PROCspline1(0,1,0,1)
 1650 IF XS<>0 PROCspline1(2*XS,-1,0,1)
 1660 IF YS<>0 PROCspline1(0,1,2*YS,-1)
 1670 IF XS<>0 AND YS<>0 PROCspline1(2*XS,-1,2*YS,-1)
 1680 ENDPROC
 1690 :
 1700 DEF PROCspline1(xc,xm,yc,ym)
 1710 FOR N%=0 TO L%-1
 1720 x=FNd(1+2*N%,xc,xm):Y%(N%+1)=FNx(x)
 1730 y=FNd(2*(N%+1),yc,ym):X%(N%+1)=FNy(y)
 1740 NEXT N%
 1750 FOR J%=1 TO L%
 1760 apeX%(J%)=((X%(J%)*4)-X%(J%+1)-X%(J%-1))/2
 1770 apeY%(J%)=((Y%(J%)*4)-Y%(J%+1)-Y%(J%-1))/2
 1780 NEXT
 1790 MOVE X%(1),Y%(1)
 1800 FOR J%=1 TO L%-2
 1810 FOR n=0 TO 0.5 STEP .02
 1820 N=1-n:m=n*2:M=1-m
 1830 IF J%=1 PROCsimplebow(J%)
 1840 IF J%>1 PROChalfbow
 1850 NEXT:NEXT
 1860 FOR n=0.5 TO 1 STEP .02
 1870 PROCsimplebow(J%-1)
 1880 NEXT n
 1890 DRAW FNrx(X%(J%+1)),FNry(Y%(J%+1))
 1900 ENDPROC
 1910 :
 1920 DEF PROCsimplebow(J%)
 1930 DRAW FNrx(FNbowX(J%,n)),FNry(FNbowY(J%,n))
 1940 ENDPROC
 1950 :
 1960 DEF PROChalfbow
 1970 LOCAL BowX,BowX2,BowY,BowY2
 1980 BowX=m*FNbowX(J%,n)
 1990 BowX2=M*FNbowX(J%-1,n+.5)
 2000 BowY=m*FNbowY(J%,n)
 2010 BowY2=M*FNbowY(J%-1,n+.5)
 2020 DRAW FNrx(BowX+BowX2),FNry(BowY+BowY2)
 2030 ENDPROC
 2040 :
 2050 DEF FNbowX(J%,n)
 2060 LOCAL X%,X2%,apeX%
 2070 X%=X%(J%):X2%=X%(J%+2)
 2080 apeX1%=apeX%(J%+1)
 2090 =((X%+(n*(apeX1%-X%)))*(1-n))+((apeX1%+(n*(X2%-apeX1%)))*n)
 2100 :
 2110 DEF FNbowY(J%,n)
 2120 LOCAL Y%,Y2%,apeY%
 2130 Y%=Y%(J%):Y2%=Y%(J%+2)
 2140 apeY1%=apeY%(J%+1)
 2150 =((Y%+(n*(apeY1%-Y%)))*(1-n))+((apeY1%+(n*(Y2%-apeY1%)))*n)
 2160 :
 2170 DEF FNx(pos)=1023-xsc*pos
 2180 DEF FNy(pos)=ysc*pos
 2190 DEF FNrx(x):IF x<0 THEN =0
 2200 IF x>1279 THEN =1279 ELSE =x
 2210 DEF FNry(y):IF y<0 THEN =0
 2220 IF y>1023 THEN =1023 ELSE =y
 2230 :
 2240 DEF FNt(P%)=(ASC(MID$(S$,P%,1))-48)/2
 2250 DEF FNd(P%,c,m)=c+m*FNt(P%)
 2260 :
 2270 DEF PROCdumpletter
 2280 ?dots=16/xdpp
 2290 lines%=INT(.99999999+(4+xmax*xsc)/64)
 2300 len%=INT(.99999999+28*ysc/16)
 2310 PROCdump:PROCls(20*xsize)
 2320 ENDPROC
 2330 :
 2340 DEF PROCdump
 2350 FOR Y%=0 TO (xdpp*lines%)-1
 2360 IF xdpp=1 x%=&500*Y% ELSE IF xdpp=2 x%=&280*Y% ELSE x%=&280*(Y% DIV 2)+4*(Y% MOD 2)
 2370 !adr=&3000+x%:?len=len%
 2380 CALL main:PROCprint:PROCls(1)
 2390 IF xdpp=1 !adr=&3001+x%:?len=len%:CALL main
 2400 PROCprint:PROCls(23)
 2410 NEXT Y%:ENDPROC
 2420 :
 2430 DEF PROCls(L%)
 2440 VDU 1,27,1,51,1,L%,1,13,1,10
 2450 ENDPROC
 2460 :
 2470 DEF PROCprint
 2480 VDU 1,27,1,90,1,(8*len%*ydpp) MOD&100,1,(8*len%*ydpp) DIV&100
 2490 FOR I%=0 TO (8*len%-1)
 2500 FOR J%=1 TO ydpp
 2510 VDU 1,I%?store%
 2520 NEXT ,:ENDPROC
 2610 :
 2620 DATA L0h,22,L,L;D;@101DgLg,L,LUFCLC,E
 2630 DATA 00_,22,L,N1010gNg,S,NgVdZ`\[[TWO,S,WO]H_@Z5N1,L,JR@R@ZJZ,S,JZMYOVMSJR,L,L=@=@GLG,S,LGPEQBP?L=,E
 2640 DATA 0Ld,J2,S,dFb>X4K0>44>0L,S,UFRAK>DAAF@L,L,dFUF,E
 2650 DATA 0Lb,22,L,0L01M1,S,M1X5`?bL,L,@L@>F>,S,F>L@QERL,E
 2660 DATA 0L^,22,L,0M01^1^?@?@GZGZM,E
 2670 DATA 00Z,22,L,01@1@CVCVQ@Q@YZYZg0g01,E
 2680 DATA 00d,J2,S,Y7R2K0>44>0L4Z>dKhXdbZdR,S,UCQ?K>DAAF@LARDWKZRWUR,L,UCNCNNdNd1Z1Y7,L,dRUR,E
 2690 DATA LLh,22,L,0N01@1@CLC,E
 2700 DATA 8L@,22,L,0M0181,E
 2710 DATA 00X,D2,L,HCHgXgXE,S,0E2;75D1Q5V;XE,L,0E0I@I@C,S,@CA@D?G@HC,E
 2720 DATA 00d,22,L,010g@g@VOgbgPRd1R1DE@A@101,E
 2730 DATA 00X,22,L,010g@g@AXAX101,E
 2740 DATA M0j,22,L,M1G1>P>1010gFgMJ,E
 2750 DATA 00`,22,L,010gAgOIOg`g`1O1ANA101,E
 2760 DATA KLf,K2,S,K0>44>0L,S,K?DBAG@L,E
 2770 DATA 00_,22,L,LB@B@1010gLg,S,LgVd\^_U\KVELB,L,IN@N@ZIZ,S,IZMXOTMPIN,E
 2780 DATA 00f,J2,S,K0>44>0L4Z>dKhXdbZfLb>,L,b>f>f0K0,S,K?DBAG@LAQDVKYRVUQVLUGRBK?,E
 2790 DATA 00`,22,L,FC@C@1010gOg,S,Og[a`W^NXI,S,XI[F^A_;_3a1,L,a1P1,S,P1N=KBFC,L,IM@M@YIY,S,IYMWOSMOIM,E
 2800 DATA 00\,F2,S,\WZ_SeFh9e2_0W0U2O9HFDIAG=D<A=?A,S,0A2993F0S3Z9\BZISPFTCWE[H\K[MW,L,\WMW,L,?A0A,E
 2810 DATA G0^,2f,L,G1?1?Y0Y0gGg,E
 2820 DATA I0b,2f,L,0D0g@g@D,S,@DB?I=,S,0D1<65=1I0,E
 2830 DATA H0`,2f,L,HD@g0g?1H1,E
 2840 DATA T0x,2f,L,TQN1=10g?gFCMgTg,E
 2850 DATA KLf,22,L,KVDg0g=L,E
 2860 DATA K0f,2f,L,KSBg0gBEB1K1,E
 2870 DATA 00g,22,L,\g0g0YHY0?01\1\?D?\Y\g,E
 2880 DATA 00>,22,L,01>1>?0?01,E
 2890 DATA 00>,225H,L,01>1>?0?01,L,4E0Y0f>f>Y:E4E,E
 2900 DATA 00>,44,L,030?>?>3;0407303,E