5 REM SAVE"CALNDER"    
   10 REM CALENDAR
   11 REM This CALENDAR was first issued in LET'S COMPUTE! in January 1991 and isprinted here with the kind permission ofSteve Turner the Editor of Acorn User onNovember 21 1996,  Fred Price.
   20 REM (C) LET'S COMPUTE!
   30 MODE 0
   40 LET W=80
   50  LET S$="   ":FOR I=1 TO 3:LET S$=S$+S$:NEXTI:REM THERE ARE THREE SPACES BETWEEN THE QUOTES    
   60 LET MW=INT (W/24):LET MARGIN=INT ((W-24*MW)/2)  
   70 DIM M$(12):DIM T(12):DIM W$(6,3)
   80 FOR I=1 TO 12
   90 READ M$(I),T(I)
  100 NEXT I
  110 LET D$="  SU MO TU WE TH FR SA  "
  120 INPUT "Printer or screen (P/S)";P$
  130 INPUT"What year"; YEAR
  140 CLS
  150 LET B$="":IF W>33 THEN LET B$=LEFT$(S$,INT((W-32)/2))
  160 LET A$=B$+"The Let's Compute Calendar "+STR$(YEAR)
  170 GOSUB 570
  180 LET A$=" ":GOSUB 570
  190 READ A$:IF A$<>"end" THEN LET A$=B$+A$:GOSUB 570:GOTO 190
  200 GOSUB 600
  210 LET T(2)=28
  220 LET Y4=INT (YEAR/4):LET SD=YEAR+Y4-7*INT ((YEAR+Y4)/7)
  230 IF YEAR=4*Y4 THEN LET SD=SD-1:LET T(2)=29
  240 LET X=(SD-1)*3+1
  250 IF SD<=0 THEN LET X=X+21
  260 LET MNTH=0
  270 REM
  280 FOR J=1 TO MW
  290 LET R=1
  300 LET X$=LEFT$(S$,X)
  310 FOR I=1 TO T(MNTH+J)
  320 LET T=INT (I/10)
  330 LETU=I-10*T+48:LET T=T+48
  340 IF T=48 THEN LET T=32
  350 LET X$=X$+" "+CHR$(T)+CHR$(U)
  360 LET SD=(SD+1)
  370 LET X=(X+3)
  380  IF X>21 THEN LET X=1:LET W$(R,J)=LEFT$(X$+S$,24):LET R=R+1:LET X$=" "
  390 NEXT I
  400 LET W$(R,J)=LEFT$(X$+S$,24)
  410 LET R=R+1:IF R<7 THEN LET W$(R,J)=S$:GOTO410  
  420 NEXT J
  430 LET A$=" ":GOSUB 570:LET A$=LEFT$(S$,MARGIN)
  440 FOR J=1 TO MW:LET A$=A$+LEFT$("  "+M$(MNTH+J)+S$,24):NEXT J  
  450 GOSUB 570:LET A$=" ":GOSUB 570:LET A$=LEFT$(S$,MARGIN)
  460 FOR J=1 TO MW: LET A$=A$+D$:NEXT J    
  470 FOR R=1 TO 6
  480 GOSUB 570:LET A$=LEFT$(S$,MARGIN)
  490 FOR J=1 TO MW
  500 LET A$=A$+W$(R,J)
  510 NEXT J
  520 NEXT R
  530 GOSUB 570
  540 GOSUB 600
  550 LET MNTH=MNTH+MW:IF MNTH<12 THEN GOTO 270
  560 END
  570 REM PRINT A$
  580 IF P$="P" OR P$="p" THEN VDU2 
  590 PRINT A$:VDU3:RETURN
  600 REM WAIT FOR SPACE 
  610 IF P$="P" ORP$="p" THEN RETURN
  620 AA=GET
  630 RETURN
  640 REM MONTH DATA
  650 DATA "JANUARY",31 
  660 DATA "FEBRUARY",28
  670 DATA "MARCH",31 
  680 DATA "APRIL",30
  690 DATA "MAY",31
  700 DATA "JUNE",30
  710 DATA "JULY",31
  720 DATA "AUGUST",31
  730 DATA "SEPTEMBER",30
  740 DATA "OCTOBER",31
  750 DATA "NOVEMBER",30
  760 DATA "DECEMBER",31
  770 DATA"   /*\/*\     Mabel"
  780 DATA"   ******     Says"
  790 DATA"\_**O**O**_/ Welcome"
  800 DATA"__***<>***__   To   "
  810 DATA"  * **** *    Lets"
  820 DATA" /**    **\  Compute"
  830 DATA"   ******"
  840 DATA"     **"
  850 DATA"    *OO*"
  870 DATA"   *OOOO*" 
  880 DATA"  *OOOOOO*"
  890 DATA"  **OOOO**      *"    
  900 DATA"  ***OO***     ***"  
  910 DATA"  ********     000"     
  920 DATA" **==OO==**    ***"   
  930 DATA" **==OO==**    000"   
  940 DATA" **==OO==**    ***"  
  950 DATA" **==OO==**    000"  
  960 DATA" **==OO==**   0**"
  970 DATA"***==OO==**0*0*0"
  980 DATA"***==OO==**0*0*" 
  990 DATA" **nnnnnn**"
 1000 DATA"##################"
 1010 DATA"end"