10 MODE7
   20 *KEY10"OLD|M"
   30 HIMEM=&6B00
   40 d1$=CHR$130+CHR$141
   50 d2$=CHR$131+CHR$141
   60 PRINTd1$"    DFS Disc Image Extractor"
   70 PRINTd2$"    DFS Disc Image Extractor"
   80 PRINT
   90 PRINT"What with the difficulty of getting"
  100 PRINT"hold of DD discs, a problem that can"
  110 PRINT"only get worse in the near future, we"
  120 PRINT"are likely to see alot more utilities"
  130 PRINT"similar to this one."
  140 PRINT
  150 PRINTd1$"Place a formated DFS disc in drive 1"
  160 PRINTd1$"Place a formated DFS disc in drive 1"
  170 PRINTd1$"and press Return."
  180 PRINTd1$"and press Return."
  190 REPEAT
  200 K$=GET$
  210 PRINTTAB(0,16)d2$"Are You Sure? y/n "
  220 PRINTTAB(0,17)d2$"Are You Sure? y/n "
  230 UNTILINSTR("YyNn",K$)
  240 IFINSTR("Nn",K$):PRINTTAB(2,16)"Operation Aborted!":PRINTTAB(2,17)"Operation Aborted!":END
  250 secnum%=10
  260 B%=&900:I%=&910
  270 FS$="ADFS":drive%=1
  280 OSCLIFS$
  290 *MOUNT 0
  300 F$="ARCADE"
  310 F%=OPENINF$
  320 :
  330 PRINTTAB(2,16)"Extracting Track "CHR$134
  340 PRINTTAB(2,17)"Extracting Track "CHR$134
  350 REPEAT
  360 track%=(PTR#F%DIV256)DIV 10
  370 OSCLIFS$
  380 PROCread_data
  390 PRINTTAB(25,16)STR$(track%)
  400 PRINTTAB(25,17)STR$(track%)
  410 A=INKEY(100)
  420 *DISC
  430 PROCwrite_track(drive%)
  440 A=INKEY(100)
  450 UNTILEOF#F%
  460 :
  470 CLOSE#F%
  480 *DISC
  490 *DR.1
  500 CHAIN"MENU"
  510 END
  520 :
  530 DEFPROCread_data
  540 B%?0=F%
  550 B%!1=HIMEM
  560 B%!5=secnum%*256
  570 A%=4
  580 X%=B% MOD 256
  590 Y%=B% DIV 256
  600 CALL&FFD1
  610 ENDPROC
  620 :
  630 DEFPROCwrite_track(drv%)
  640 ?I%=drv%
  650 I%!1=HIMEM
  660 I%?5=3
  670 I%?6=&4B
  680 I%?7=track%
  690 I%?8=0
  700 I%?9=&20+&A
  710 A%=&7F
  720 X%=I% MOD 256
  730 Y%=I% DIV 256
  740 CALL&FFF1
  750 IFI%?10>0:PRINT"ERROR "I%?10:END
  760 ENDPROC