10 DEFFNS="HTMRead"
   20 E%=0
   30 MODE0
   40 VDU14
   50 PRINT'"HTML Reader"''
   60 PRINT"Press SHIFT to scroll the text"''
   70 PRINT"Do you want to see the jumps? Y/N"''
   80 *FX21
   90 REPEAT
  100 E$=GET$
  110 UNTILINSTR("YyNn",E$)
  120 IF INSTR("Yy",E$):E%=1:PRINT"You will now see:"'"Links within pages (GO TO #)"'"Links to other pages (GO TO)"'"Names of graphics (GRAPHIC) and alternate text (ALT TEXT)"''
  130 REPEAT
  140 *.
  150 PRINT''"Enter Filename to read, *COMAND OR RETURN for Default (8BS Front Page)"''
  160 *FX21
  170 INPUT F$
  180 IF LEFT$(F$,1)="*":OSCLI F$
  190 UNTILLEFT$(F$,1)<>"*"
  200 IF F$="" F$="MAINHTM"
  210 F%=OPENIN (F$)
  220 REPEAT
  230 A%=BGET#F%
  240 IF A%<>ASC"<" VDUA%
  250 IF A%=ASC"<":PROCjump
  260 UNTILEOF#F%
  270 CLOSE#F%
  280 *FX21
  290 PRINT'''"*TYPE the file? ";F$;" Y/N"
  300 B$=GET$
  310 IF B$="Y" OR B$="y":OSCLI("TYPE "+F$)
  320 PRINT''"PRESS A KEY"''
  330 REPEATUNTILGET
  340 RUN
  350 DEFPROCjump
  360 A$=""
  370 REPEAT
  380 B%=BGET#F%
  390 A$=A$+CHR$(B%)
  400 UNTILB%=ASC">" OR EOF#F%
  410 IF E%=0 ENDPROC
  420 REM FIND COMMANDS
  430 IF INSTR(A$,"SRC"):C%=INSTR(A$,"SRC"):PROCname("GRAPHIC")
  440 IF INSTR(A$,"HREF"):C%=INSTR(A$,"HREF"):PROCname("GO TO")
  450 IF INSTR(A$,"ALT"):C%=INSTR(A$,"ALT"):PROCname("ALT TEXT")
  460 REM LOADS MORE COULD BE ADDED HERE!
  470 ENDPROC
  480 DEFPROCname(C$)
  490 REM FIND INVERTED COMMAS
  500 REPEAT
  510 C%=C%+1
  520 UNTIL MID$(A$,C%,1)=CHR$(34)
  530 REM PRINT INFO
  540 PRINT" ";C$;" ";
  550 REM PRINT EVERYTHING BETWEEN INVERTED COMMAS
  560 REPEAT
  570 PRINTMID$(A$,C%,1);
  580 C%=C%+1
  590 UNTILMID$(A$,C%,1)=CHR$(34)
  600 PRINT""" ";
  610 ENDPROC